Actualizado:

1. Consultarlo una vez

/time query minecraft:day repetitions
/time query minecraft:day

Java 26.1 y posteriores. En 1.21.11 y anteriores, y en Bedrock, usa /time query day y /time query daytime. Consulta el comando time.

2. Número de días en la barra lateral (iterativo)

/scoreboard objectives add day dummy "Días del mundo"
/scoreboard objectives setdisplay sidebar day

Ejecuta esto una vez y pon esto en un bloque de comandos iterativo:

/execute store result score Día day run time query minecraft:day repetitions

Usa time query day en 1.21.11 y anteriores. Los nombres que empiezan por # no se muestran en la barra lateral.

3. Preparar el reloj (una vez)

/scoreboard objectives add clock dummy
/scoreboard players set #24000 clock 24000
/scoreboard players set #1000 clock 1000
/scoreboard players set #24 clock 24
/scoreboard players set #60 clock 60
/scoreboard players set #6 clock 6

Un día son 24000 ticks, la hora 0 son las 6:00 de la mañana y 1000 ticks son una hora.

4. Reloj (iterativo)

/execute store result score #t clock run time query minecraft:day
/scoreboard players operation #t clock %= #24000 clock
/scoreboard players operation #h clock = #t clock
/scoreboard players operation #h clock /= #1000 clock
/scoreboard players operation #h clock += #6 clock
/scoreboard players operation #h clock %= #24 clock
/scoreboard players operation #m clock = #t clock
/scoreboard players operation #m clock %= #1000 clock
/scoreboard players operation #m clock *= #60 clock
/scoreboard players operation #m clock /= #1000 clock
/title @a actionbar [{"score":{"name":"#h","objective":"clock"}},{"text":":"},{"score":{"name":"#m","objective":"clock"}}]

Usa time query daytime en la primera línea en 1.21.11 y anteriores. Los minutos por debajo de 10 salen con una sola cifra, como 13:5.

5. Mensaje de nuevo día (iterativo)

/execute unless score Día day = #prev day run title @a title [{"text":"Día "},{"score":{"name":"Día","objective":"day"}}]
/scoreboard players operation #prev day = Día day

Encadénalos después del paso 2. El título sale una vez cada vez que cambia el día, también después de dormir.

Solución de problemas

Comprueba tu comando

El Command Error Doctor (en inglés) revisa en tu navegador los errores de sintaxis más comunes.