Mise à jour :

1. Règles (une fois)

/gamerule natural_health_regeneration false
/difficulty hard
/gamerule keep_inventory false

En 1.21.10 et antérieur, la première règle s'appelle naturalRegeneration. Voir la liste des règles de jeu.

2. Afficher la vie

/scoreboard objectives add hp health "♥"
/scoreboard objectives setdisplay list hp
/scoreboard objectives setdisplay below_name hp

3. Bordure du monde (une fois)

/worldborder center 0 0
/worldborder set 1000

4. Départ : répartir les joueurs

/scoreboard objectives add died deathCount
/scoreboard players set @a died 0
/gamemode survival @a
/effect give @a instant_health 1 10 true
/spreadplayers 0 0 150 450 false @a
/worldborder set 50 3600s

Les joueurs sont placés dans un rayon de 450 blocs autour du centre, à au moins 150 blocs les uns des autres. Utilisez true pour garder les équipes ensemble. La bordure rétrécit ensuite à 50 blocs en une heure. Depuis Java 1.21.11, la durée est en ticks sauf si vous ajoutez s ; en 1.21.10 et antérieur, écrivez 3600 (secondes).

5. Les joueurs tombés deviennent spectateurs (Répétition)

/gamemode spectator @a[scores={died=1..},gamemode=survival]

6. Gagnant (Répétition)

/scoreboard objectives add uhc dummy
/execute store result score #alive uhc if entity @a[gamemode=survival]
/execute if score #alive uhc matches 1 unless entity @e[type=marker,tag=uhc_end] run title @a title [{"selector":"@a[gamemode=survival]"},{"text":" gagne !"}]
/execute if score #alive uhc matches 1 unless entity @e[type=marker,tag=uhc_end] run summon marker ~ ~ ~ {Tags:["uhc_end"]}

Lancez la première ligne une fois. Le marqueur fait que le titre ne s'affiche qu'une fois ; supprimez-le avant la partie suivante.

Dépannage

Vérifiez votre commande

Le Command Error Doctor (en anglais) vérifie dans votre navigateur les erreurs de syntaxe les plus courantes.